ESP32 简单的WEB Server和GET参数读取示例

2023年6月16日2023年6月26日 lingshun

要在ESP32上启动一个Web服务器，您可以使用Arduino IDE和ESPAsyncWebSrv库。以下是一个简单的示例，说明如何设置一个基本的Web服务器：

Arduino IDE中安装了ESP32开发板

首先，确保您已经在Arduino IDE中安装了ESP32开发板。如果尚未安装，请按照以下链接的说明进行操作：https://github.com/espressif/arduino-esp32/blob/master/docs/arduino-ide/boards_manager.md

安装所需的库

接下来，安装所需的库。在Arduino IDE中，转到“工具”>“管理库”，然后搜索并安装以下库：

ESPAsyncWebSrv
AsyncTCP（仅适用于ESP32）
ESPAsyncTCP（仅试用于ESP8266）

程序代码

创建一个新的Arduino项目，并将以下代码粘贴到项目中：

// welcome to lingshunlab.com

// A simple server implementation showing how to:
//  * serve static messages
//  * read GET parameters
//  * handle missing pages / 404s

#include <Arduino.h>
#ifdef ESP32
#include <WiFi.h>
#include <AsyncTCP.h>
#elif defined(ESP8266)
#include <ESP8266WiFi.h>
#include <ESPAsyncTCP.h>
#endif
#include <ESPAsyncWebSrv.h>

AsyncWebServer server(80);

const char* ssid = "YOUR_SSID";
const char* password = "YOUR_PASSWORD";

const char* PARAM_MESSAGE = "message";

void notFound(AsyncWebServerRequest *request) {
    request->send(404, "text/plain", "Not found");
}

void setup() {

    Serial.begin(115200);
    WiFi.mode(WIFI_STA);
    WiFi.begin(ssid, password);
    if (WiFi.waitForConnectResult() != WL_CONNECTED) {
        Serial.printf("WiFi Failed!\n");
        return;
    }

    Serial.println("WIFI connected!");

    Serial.print("IP Address: ");
    Serial.println(WiFi.localIP());

    server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
        request->send(200, "text/plain", "Hello, world");
    });

    // Send a GET request to <IP>/get?message=<message>
    server.on("/get", HTTP_GET, [] (AsyncWebServerRequest *request) {
        String message;
        if (request->hasParam(PARAM_MESSAGE)) {
            message = request->getParam(PARAM_MESSAGE)->value();
        } else {
            message = "No message sent";
        }
        request->send(200, "text/plain", "Hello, GET: " + message);
    });

    // Send a POST request to <IP>/post with a form field message set to <message>
    server.on("/post", HTTP_POST, [](AsyncWebServerRequest *request){
        String message;
        if (request->hasParam(PARAM_MESSAGE, true)) {
            message = request->getParam(PARAM_MESSAGE, true)->value();
        } else {
            message = "No message sent";
        }
        request->send(200, "text/plain", "Hello, POST: " + message);
    });

    server.onNotFound(notFound);

    server.begin();
}

void loop() {
}