Arduino Uno 点亮WS2812B 彩色LED灯条

实验效果

Arduin Uno 点亮WS2812B，实现单个控制和彩虹走马灯效果。

元件说明

WS2812B是一个集控制电路与发光电路于一体的智能外空LED光源。其外形与一个5050LED灯珠相同，每个元件即为一个像素点。像素点内部包含了智能数字接口数据锁存信号整形放大电路，还包括有高精度的内部振荡器和可编程电流控制部分，有效保证了像素点的颜色高度一致。

数据协议采用单线归零码的通讯方式，像素点在上电复位以后，DIN端接受从控制器传输过来的数据，首先 送过来的24bit数据被第一个像素点提取后，送到像素点内部的数据锁存器，剩余的数据经过内部整形处理电路 整形放大后通过DO端口开始转发输出给下一个级联的像素点，每经过一个像素点的传输，信号减少24bit。像素 点采用自动整形转发技术，使得该像素点的级联个数不受信号传送的限制，仅仅受限信号传输速度要求。

LED具有低电压驱动，环保节能，亮度高，散射角度大，一致性好，超低功率，超长寿命等优点。将控制电 路集成于LED上面，电路变得更加简单，体积小，安装更加简便。

引脚说明

5V ：电源，供电5V

GND ：地信号，接地

DI ：数据输入，控制数据信号输入

DO ：数据输出，控制数据信号输出

BOM表

名称	数量
Arduino Uno	x1
WS2812B 灯条（24灯）	x1
跳线（杜邦线）	若干

接线方式

Arduino Uno 引脚	<->	WS2812B 引脚
5V	<->	5V（PWR）
GND	<->	GND（G）
3	<->	DI（IN）

提点

安装FastLED库

需要安装FastLED库，可以在Arduino IDE 的「库管理」中搜索「FastLED」即可安装使用。

这是一个用于轻松高效地控制各种 LED 芯片组的库，例如 adafruit（Neopixel、DotStar、LPD8806）、Sparkfun（WS2801）和 aliexpress 销售的芯片组。除了写入 LED 之外，该库还包括许多用于处理 RGB 值的高性能 8 位数学函数，以及用于抽象出对引脚和 SPI 硬件的访问的低级类，同时仍然保持速度一样快尽可能。

github地址：https://github.com/FastLED/FastLED

程序代码

// by lingshunlab.com
// 本示例程序适用于3线（电源线，地线，数据线）的WS2812灯条

#include <FastLED.h>
#define NUM_LEDS 24 // 定义 led 数量
#define DATA_PIN 3 // 定义 开发板的IO 3 为数据引脚

CRGB leds[NUM_LEDS]; // 定义CRGB的led等数组

void setup() {
  FastLED.addLeds<NEOPIXEL, DATA_PIN>(leds, NUM_LEDS);     
}

void loop() { 
  // 第一个led灯闪烁白色
  leds[0] = CRGB::White; // 序号为0的led设置白色，点亮
  FastLED.show();
  delay(500);
  leds[0] = CRGB::Black; // 序号为0的led设置黑色，熄灭
  FastLED.show();
  delay(500);

  delay(500);

  // 每一个led逐个闪烁绿色
  for(int i = 0; i < NUM_LEDS; i++ ) {
    leds[i] = CRGB::Green;
    FastLED.show();
    delay(100);
    leds[i] = CRGB::Black;
    FastLED.show();
    delay(100);
  }

  delay(1000);

  // 整个灯条 彩虹色渐变
  int h = 0;
  for(int j = 0; j< 255; j++) {
    for (int i = 0; i < NUM_LEDS; i++) {
      leds[i] = CHSV( (h + (255 / NUM_LEDS) * i), 255, 255); //用HSV色彩空间，不断改变H即可
      FastLED.show();
    }
    delay(1);
    h = (h + 2) % 255;
  }

  // 整个灯条熄灭
  for(int i = 0; i < NUM_LEDS; i++ ){
    leds[i] = CRGB::Black;
  }
  FastLED.show();

  delay(1000);
}